Aplikasi Stok Excel Dengan Dua Harga Penjualan Berbeda

Halo Sobat Belajar Office. Pada artikel sebelumnya admin sudah membahas Aplikasi stok barang menggunakan rumus Excel. Kali ini admin akan membahas update terbaru dengan sedikit penambahan dari Aplikasi Stok Excel Dengan Dua Harga Penjualan Berbeda jadi ada harga jual grosiran dan harga ecerannya yang berbeda. Pada contoh aplikasi stok ini admin buat harga jual lusinan dan harga jual satuan yang berbeda. Seperti misalnya jika ada yang membeli barang dalam jumlah banyak contohnya 1 lusin maka harganya lebih murah, dari pada yang membeli eceran 1 pcs.

Langsung saja berikut ini cara membuatnya:

Rumus-rumusnya masih sama dengan aplikasi stok pertama, hanya ada beberapa penambahan sepeti stok awal harga jual lusinan.

Sheet1 diberi nama “input barang”

Sheet ini digunakan untuk menginput data barang meliputi : no, kode barang, nama barang, harga beli satuan, harga jual satuan, terdapat penambahan untuk harga jual lusinan (grosir), ada juga stok awalnya dan jml barang kolom ini inputnya dari sheet2 (tambah stok) jadi ketika barang diinput di sheet2 jumlah akan terakumulasi otomatis ditambah dengan stok awal.

Pada contoh ini untuk harga beli admin asumsikan penjual hanya menyetok barang dengan jumlah grosiran pada contoh tersebut lusin.

Rumus yang digunakan rumus Excel SUMIF

pada cell E5 ketikan rumus

=SUMIF(‘tambah stok’!C:C;B6;’tambah stok’!E:E)+D6

Sheet2 diberi nama “tambah stok”

Sheet2 ini digunakan untuk input menambah stok barang, terdiri dari kolom sebagai berikut : no, tanggal, kode barang, nama barang, jumlah

Tanggal untuk input tanggal kapan barang ditambah stoknya

Kode Barang supaya lebih praktis, dibuat data validation dengan list drop down dengan data dari sheet1 kolom kode barang sehingga praktis tinggal pilih saja.

Nama barang dibuat otomatis muncul ketika kode barang diinput.

Rumus yang digunakan Vlookup tipe False, kemudian disempurnakan dengan rumus IFERROR tujuanya untuk menghilangkan pesan error, sehingga format tampil bersih dan lebih rapih.

Rumusnya :

=IFERROR(VLOOKUP(C5;’input barang’!B:C;2;FALSE());” “)

Jumlah digunakan untuk menginput jumlah barangnya, sekali lagi admin asumsikan bahwa input stoknya dalam jumlah grosiran pada contoh ini lusinan

sheet3 diberi nama “penjualan”

Sheet3 ini digunakan untuk input penjualan barang perharinya, terdiri dari kolom no, tgl, kode, nama barang, jml, satuan, harga jual, total harga.

untuk kode barang bisa dibuat sama seperti di sheet2 gunakan Data validation.

Nama barang dan Harga Jual dibuat juga otomatis dengan rumus vlookup digabung iferror supaya rapih

rumusnya :

Nama barang

=IFERROR(VLOOKUP(C5;’input barang’!$B:$F;2;FALSE());” “)

jumlah

Untuk input jumlah penjualan barang, selanjutnya pilih satuanya : Lusin atau pcs

Harga jual

Pada klom ini tentunya rumusnya harus dibuat supaya bisa menampilkan harga Lusin atau satuan dengan menggunaka rumus IF dan Vlookup dari sheet input barang.

=IFERROR(IF(F5=satuan!$A$4;VLOOKUP(C5;’input barang’!$B:$H;7;FALSE());VLOOKUP(C5;’input barang’!$B:$H;6;FALSE()));””)

Total Harga

= Jml * Harga jual

Rumus disempurnakan dengan IFERROR

=IFERROR(E5*G5;””)

Total Penjualan

=SUM(H:H)

sheet4 dengan nama “laporan”

Dari sheet ini kita bisa memantau penjualan, keutungan, stok tersedia dll

Sheet laporan terdiri dari kolom : no, kode barang, nama barang, harga beli (lusin),  jumlah terjual, sisa stok, jumlah penjualan lusin, jml penjualan psc, total penjualan dan keuntungan.

Kode barang, nama barang, harga beli  sama dengan sheet1 “input barang”

Jml terjual rumusnya

=IF(ISBLANK(‘input barang’!B6);””;(SUMIFS(penjualan!E:E;penjualan!F:F;satuan!$A$4;penjualan!C:C;B6)*satuan!$B$4+SUMIFS(penjualan!E:E;penjualan!F:F;satuan!$A$3;penjualan!C:C;B6))/satuan!$B$4)

Sisa Stok

=(‘input barang’!E6)-E6

Jml Penjualan (lusin)

=SUMIFS(penjualan!H:H;penjualan!F:F;satuan!$A$4;penjualan!C:C;laporan!B6)

Jml Penjualan (pcs)

=SUMIFS(penjualan!H:H;penjualan!F:F;satuan!$A$3;penjualan!C:C;laporan!B6)

Total Penjualan

=G6+H6

Keuntungan

=IFERROR(I6-(D6*E6);””)

sheet5 dengan nama “satuan”

Pada aplikasi stok update ini juga sudah disetting jika sobat ingin menganti satuan untuk grosirannya misalnya bisa diganti dengan rim, kodi, pak dsb.Untuk yang lusinan sedangkan yang Pcs tidak bisa diganti. kemudian jumlnya juga harus diganti misalnya kodi jml 20.

untuk file yang sudah jadi bisa sobat download pada link dibawah ini

Aplikasi Stok Excel Dengan Dua Harga Penjualan Berbeda

File ini masih dalam tahap uji coba, dan masih banyak kekurangan, jika masih ada error atau salah perhitungan silahkan laporkan pada kolom komentar, dan  bisa dikembangkan lagi sesuai dengan kemauan masing-masing.

Terimakasih semoga bermanfaat.